กระทู้ที่ 0131
สงสัยเกี่ยวกับการใช้จํานวนเชิง…
ตั้งกระทู้ใหม่

ช่วยแนะนําการใช้โปรแกรมคํานวณ Maple 10 ทีครับ.ตอบ: 10, อ่าน: 20125, แท็ก: แนะนำ, maple, วิธีใช้

คือผม งง อะครับ... ไม่เคยใช้โปรแกรมด้านนี้มาก่อนเลย...

พอ installเส็ดมันก้อจะขึ้น Maple Classic WorkSheet , Maple Calculator , Maple 10

อยากทราบเวลาจะคํานวณจะไรสักอย่างนึก ต้องใช้ตัวไหนอ่าครับ แล้วต้องมีขั้นตอนคร่าว ๆ ในการทํายังไงอะครับ แบบต้องพิมพ์เป็นคําสั่งหรือ  code แบบในนี้หรือเปล่าช่วยอธิบายให้หน่อยครับ..

ขอบคุณครับ..
นิรนาม.. 22/09/49 21:39 
ถ้าจะใช้ คำนวนขั้นสูงใช้ Maple 10 ครับ


เล้ง 22/09/49 21:56  [ 1 ] 
แหม่ พอดีเลยครับ ผมก็ใช้ Maple ครับ.. (vers 9.5)
แต่ไม่เคยใช้แบบตัวเต็มๆ เลยครับ ใช้แต่ classic worksheet
เพราะว่าก่อนหน้าที่จะใช้ v9.5 ผมใช้ v5.0 อ่ะครับ ซึ่งเป็นรูปแบบ classic worksheet นี่ล่ะครับ..

โปรแกรมนี้ใช้ลำบากเพราะยังไม่มีคู่มือที่เป็นภาษาไทยขายซักที
เลยต้องอ่านใน help เอาครับ..
นี่เป็นรายการทั้งหมดที่ผมเคยแกะตัวอย่างไว้อ่ะนะครับ ขอเอามาให้ดูครับ
(วิธีพิมพ์จะต้องเป็นโค้ด แต่คนละแบบกับในเว็บบอร์ดนี้นะครับ)

-----------------------------------------------------------------------------------------

** แก้สมการ
solve(x^2-2*x-3);

-----------------------------------------------------------------------------------------

** กระจายสมการ
expand((x-1)*(x-2)*(x-3)*(x+2)*(x+4));

-----------------------------------------------------------------------------------------

** แก้สมการ และกระจายสมการ
eq := (s+100)*(s+5)=0;
solve (eq);
expand (eq);

-----------------------------------------------------------------------------------------

** แก้สมการ และกระจายสมการ
a:= (x^2+5*x+6)*(x^2+20*x+96)-4*x^2;
expand(a);
solve(a);

-----------------------------------------------------------------------------------------

** แก้สมการและกระจายสมการ
eq :=(s+200)*(s+500)*(s^2+16.7*s+83.3)+2083333*(s+50) =0;
expand (eq);
solve (eq);

view full size (621 x 178 px)

-----------------------------------------------------------------------------------------

** แก้สมการที่ติดค่า i
eq:=x^2+2*(I-1)*x-1-2*I=0;
solve(eq,x);

-----------------------------------------------------------------------------------------
นวย 24/09/49 11:36  [ 2 ] 
ต่อครับๆๆ
-----------------------------------------------------------------------------------------

** แปลงลาปลาซ และแปลงกลับลาปลาซ
with(inttrans):
r := 2-t+0.5*t^2;
laplace (r,t,s);
p := (k/(s*(s+k+1)));
invlaplace (p,s,t);

-----------------------------------------------------------------------------------------

** แก้ระบบสมการ
eq1 := a+b=3*k+3;
eq2 := a*b+c=7*k+5;
eq3 := b*c=4*k+7;
solve({eq1,eq2,eq3});

-----------------------------------------------------------------------------------------

** แก้สมการ กรณีที่คำตอบเป็น RootOf...
solve(x^4+x+1,x);
allvalues(%);
evalf({%});

-----------------------------------------------------------------------------------------

** วาดกราฟ
y := 0.91*(1-exp(-11*x));
plot(y,x=0..10);

-----------------------------------------------------------------------------------------

** วาดกราฟผลตอบ e(t), เมื่อ E(s) = G(s)*R(s)
G := ((s^2)*(s+3)) / (((s^2)*(s+3))+5*s+5);
R := 2/s-1/(s^2)+1/(s^3);
with(inttrans):
e := invlaplace(G*R,s,t);
plot (e,t=0..10);

-----------------------------------------------------------------------------------------

** ตัวอย่างเพิ่มเติม การพล็อตกราฟผลตอบ Y ของระบบ
** โดยกำหนดค่า transfer function G1,G2,H และค่า input R ลงไป
G1 := 100*(s+50) / (s+200);
G2 := 41.67/(s^2+16.7*s+83.3);
H := 500/(s+500);
R := 1/s;
Y := (G1*G2*R) / (1+G1*G2*H);
with(inttrans):
y := invlaplace(Y,s,t);
plot (y,t=0..0.5);

view full size (664 x 473 px)

-----------------------------------------------------------------------------------------

การพล็อต root locus
ใช้รูป rootlocus (function, variable, range of k);
ค่า numpoints คือจำนวนจุดภายในช่วง k

with(plots,rootlocus):
rootlocus( (s^5-1)/(s^2+1), s, -5..5 );

view full size (628 x 342 px)


rootlocus( (s^5-1)/(s^2+1), s, -5..5, style=point, adaptive=false );
rootlocus( (s^5-1)/(s^2+1), s, -5..5, style=point );
rootlocus( (s^5-1)/(s^2+1), s, -5..5, style=point, numpoints=100 );

view full size (720 x 867 px)

-----------------------------------------------------------------------------------------

การแก้สมการที่มีเงื่อนไข
fsolve( eqns, vars, options );
โดยมี options ที่ใช้ได้คือ

avoid=s --- s is a set of equations of the form var=value.
complex --- Find one root (or all roots, for polynomials) over the complex floating-point numbers.
fulldigits --- This option prevents fsolve from decreasing Digits for intermediate calculations at high settings of Digits.
                 With this option fsolve may escape ill-conditioning problems, but the routine slows down.
maxsols=n --- หาคำตอบเพียง n คำตอบเท่านั้นพอ
interval --- กำหนดช่วงคำตอบ เช่น x=0..10

-----------------------------------------------------------------------------------------

ตัวอย่าง แก้สมการ node analysis ของวงจร electronics (4 node)

eq1:= (va-vs)/(rs+1/(s*cs)) + va/r12 + (va-vd)/pp + s*cm*(va-vb) =0;
eq2:= s*cm*(vb-va) + gm*(va-vd) + (vb-vd)/ro + vb/rc + s*co*(vb-vc) =0;
eq3:= s*co*(vc-vb) + vc/ll =0;
eq4:= (vd-va)/pp + vd/ee - gm*(va-vd) + (vd-vb)/ro =0;
solve ({eq1,eq2,eq3,eq4},{va,vb,vc,vd});

จะได้ค่า va,vb,vc,vd ออกมาในรูปตัวแปรอื่นๆ ที่เหลือ
คือ s,vs,rs,cs,r12,pp,cm,gm,ro,co,rc,ll,ee

-----------------------------------------------------------------------------------------

การดึงตัวร่วม จัดรูปอย่างง่าย
เช่น ดึงตัว s,co,cs ออกมาจากค่าของ vc
หรือ แยกตัวประกอบ

collect(vc,{s,co,cs},factor);

collect(vc,s,factor);

-----------------------------------------------------------------------------------------

การแทนค่า หาจุดพล็อตใน Bode เอง
gain:= 20*log((1.52*(1+25*w^2)^0.5)/((w)*((1+100*w^2)^0.5)*(1+w^2)))/2.3026;
phase:= (arctan(5*w)-arctan(10*w)-2*arctan(w)-(3.1416/2))*180/3.1416;
w:=1.801;gain;phase;

-----------------------------------------------------------------------------------------
นวย 24/09/49 11:38  [ 3 ] 

ข้อความนี้อาจมี html tag ที่ไม่อนุญาตให้แสดง
สุดท้ายครับ..
-----------------------------------------------------------------------------------------

STAT .. หาค่าต่างๆ จากตารางการแจกแจง
เริ่มโดยพิมพ์คำสั่งนี้ก่อน

with(stats):

ในการแจกแจงสติวเดนส์ที ที่ degree of freedom 2 ให้หาค่า Prob สะสม ถึง 2.92
statevalf[cdf,studentst[2]](2.92);

ในการแจกแจงสติวเดนส์ที ที่ degree of freedom 4 ให้หาค่าที่ทำให้ Prob สะสมเท่ากับ 0.90
statevalf[icdf,studentst[4]](0.90);



เปลี่ยนคำว่า cdf เป็นค่าอื่นดังนี้
cdf    cumulative density function
icdf   inverse cumulative density function
pdf    probability density function

และเปลี่ยนคำว่า studentst เป็นการแจกแจงประเภทอื่นๆ ดังนี้
ทวินาม binomiald[n, p]
ทวินามลบ negativebinomial[n, p]
เอกรูป discreteuniform[a, b]
ไฮเพอร์จีออเมตริก hypergeometric[N1, N2, n]
ปัวส์ซอง poisson[mu]
เอกรูปต่อเนื่อง uniform[a, b]
ปกติมาตรฐาน normald
ปกติ normald[mean, sd]
ไคสแควร์ chisquare[n]
สติวเดนส์ ที studentst[n]
ฟิชเชอร์ เอฟ fratio[n, m]

-----------------------------------------------------------------------------------------

การหาผลหารของพหุนาม (หารลงตัวเท่านั้น)

ใช้ divide(ตัวตั้ง,ตัวหาร,ชื่อตัวแปรที่จะเก็บค่าผลลัพธ์);

ถ้าหารลงตัวจะคืนค่า true ออกมา และเรียกดูผลลัพธ์ได้จากชื่อตัวแปรที่ตั้งไว้
(อาจไม่ใส่ชื่อตัวแปรนั้นไว้ก็ได้ หากไม่ต้องการทราบผลหาร)
แต่ถ้าหารไม่ลงตัวจะคืนค่าเป็น false, และจะไม่หาผลหารให้

เช่น
divide((6*(x^5+y^5+z^5)-5*(x^2+y^2+z^2)*(x^3+y^3+z^3)) , ((x+y+z)^2) , 'aaaa');
aaaa;

-----------------------------------------------------------------------------------------

หาค่าอนุกรม (หรือซิกม่า) ใช้ฟังก์ชัน sum
(จากตัวอย่างเหล่านี้ จะเปลี่ยนตัว k เป็น n ก็ได้)

sum('k^2', 'k'=0..4);
sum('k^2', 'k'=0..n);
sum('k^2', 'k');
sum('a[k]*x^k','k'=0..4);
sum('1/k!', 'k'=0..infinity);
sum('1/k^2', 'k'=1..infinity);
sum('(3*n+6)!/(3*n+12)!','n'=1..infinity);

-----------------------------------------------------------------------------------------

กระจายฟังก์ชันออกมาเป็นอนุกรมเทเลอร์..
series(exp(x), x=0, 8 );
series(exp(-x^2),x=0,20);
series(exp(sin(x)),x=0,8);

view full size (712 x 208 px)

-----------------------------------------------------------------------------------------

อินทิเกรตปกติ
int(exp(-x),x);
int(exp(-x),x=0..3);


อินทิเกรตประหลาดๆ (สำหรับฟังก์ชันที่อินทิเกรตปกติไม่ออก)
int(exp(sin(x)),x=0..Pi/2);
evalf(%);
int(exp(-x^2),x=0..Pi);
evalf(%);

-----------------------------------------------------------------------------------------
นวย 24/09/49 11:40  [ 4 ] 
มี tip มาฝากอีกนิดหน่อยครับ..
ถ้าใช้เฉพาะ worksheet โดยไม่ใช้พวก java maplet อะไรขั้นสูงนะครับ
เมื่อติดตั้งเสร็จแล้วสามารถเข้าไปลบโฟลเดอร์ใน Program Files ให้เหลือเพียง
โฟลเดอร์ Afm, Bin.Win, Lib, License, Users เท่านั้น..
จะประหยัดเนื้อที่ได้ราวๆ 80 MB แน่ะครับ..
นวย 24/09/49 11:45  [ 5 ] 
ดูคู่มือ หรือเข้าที่ วิธีใช้ ก็จะเป็นเอง ผมใช้เขียนกราฟ ใช้ใน cal ได้ดี เอาไว้หาคำตอบ  ศึกษาด้วยตนเอง
aaa 15/11/49 21:10  [ 6 ] 
จริงครับ :]
คนไทยไม่ค่อยชอบอ่าน Help ภาษาอังกฤษเลยครับ
ทั้งๆ ที่ในนั้นมันรวมทุกอย่างที่เราอยากรู้ไว้ให้แล้ว..
นวย 16/11/49 12:33  [ 7 ] 
😃😀😁😄🙂😆😂😲🤨😦🙄😠😤😱😨😮😳😧😳😊😬😎😔🤐😈✌️🤕😐😐😳🤭😉😴👍👍👽👉❕❔💡 งิงิ
ง่า 16/09/50 07:12  [ 8 ] 
คือผม งง อะครับ... ไม่เคยใช้โปรแกรมด้านนี้มาก่อนเลย...

พอ installเส็ดมันก้อจะขึ้น Maple Classic WorkSheet , Maple Calculator , Maple 10

อยากทราบเวลาจะคํานวณจะไรสักอย่างนึก ต้องใช้ตัวไหนอ่าครับ แล้วต้องมีขั้นตอนคร่าว ๆ ในการทํายังไงอะครับ แบบต้องพิมพ์เป็นคําสั่งหรือ  code แบบในนี้หรือเปล่าช่วยอธิบายให้หน่อยครับ..

ขอบคุณครับ..
นิรนาม.. - 22/09/49 21:39
ขอโปรแกรม ใช้บ้างได้ไหมครับ
beer 16/11/50 11:29  [ 9 ] 
ออ  มั้นแปนอะไรที่ไม่เข้าใจเหมือนกันคราฟ
เอก 28/01/51 13:37  [ 10 ] 
วิธีพิมพ์สมการดูได้ที่กระทู้ 0072 ครับ      
แปะรูป/ไฟล์
ถ้าไม่มีรหัสส่วนตัว กรุณาใส่เลขหน้า "ความน่าจะเป็น" ใน Math E-Book .. หรือตั้งรหัสได้ ที่นี่

ทดลองพิมพ์สมการ